^XA
^CI0
^PW812
^LL1218
^LH0,0

^FX// Ust serit   ^FS
^FO0,0^GB812,80,80^FS
^FO20,20^A0N,40,40^FR^FDKARISIK TEST ETIKETI^FS
^FO520,25^A0N,28,28^FR^FDTarih:^FS
^FO600,25^A0N,28^FR^FC%^FD %a, %d/%m/%Y^FS 
^FO685,50^A0N,28^FR^FC%,{,#^FD %H:%M:%S^FS 

^FX// Sol panel   ^FS
^FO20,100^A0N,30,30^FDURUN ADI:^FS
^FO20,140^A0N,46,45^FDOrnek Urun A-12345^FS
^FO20,210^A0N,24,24^FDKategori: Elektronik / Aksesuar^FS
^FO20,245^A0N,24,24^FDBatch No: TR-2026-8847-XQ^FS
^FO20,280^A0N,24,24^FDSK Barkod: 8681234567890^FS

^FX// Sag panel   ^FS
^FO420,100^GB372,200,3^FS
^FO440,120^A0N,26,26^FDDURUM:^FS
^FO440,160^A0N,60,55^FDKONTROL^FS
^FO440,230^A0N,22,22^FDOncelik: YUKSEK^FS
^FO700,230^A0N,22,22^FDRev: 3.2^FS

^FX// 1D Barkod   ^FS
^FO20,320^A0N,20,20^FD1D BARKOD (Code 128):^FS
^FO20,350^BY2,3.0,100^BCN,100,Y,N,N^FD12345678901234567890^FS
^FX// ModuleWidth=2 dot, Ratio=3.0, Height=100 dot ^FS

^FX// QR Kod      ^FS
^FO550,320^A0N,20,20^FDQR KOD:^FS
^FO550,350^BQN,2,8^FDQA,https://zebra.com/test/8681234567890^FS

^FX// DataMatrix  ^FS
^FO20,500^A0N,20,20^FDDataMatrix (2D):^FS
^FO20,530^BXN,6,200^FDKARMASIK-TEST-2026-TR-8847^FS

^FX// Dondurulmus metinler  ^FS
^FO190,500^A0N,20,20^FDDondurulmus Bilgi: (N)^FS
^FO250,530^A0N,20,20^FDABC(N)..0^FS
^FO220,550^A0R,20,20^FDABC(R).90^FS
^FO330,550^A0B,20,20^FDABC(B)180^FS
^FO250,630^A0I,20,20^FDABC(I)..0^FS

^FX// Tarih       ^FS
^FO370,540^A0N,20,20^FDTarih :^FS
^FO370,570^A0N,14^FC%,{,#^FD1: %H:%M:%S Civ: %I:%M:%S %p^FS 
^FO370,588^A0N,14^FC%,{,#^FD2: {H:{M:{S Civ: {I:{M:{S {p^FS 
^FO370,606^A0N,14^FC%,{,#^FD3: #H:#M:#S Civ: #I:#M:#S #p^FS 

^FO370,624^A0N,14^FC%,{,#^FD4: %A, %B %d, %Y (%a, %m/%d/%y, %d %b %Y).^FS 
^FO370,642^A0N,14^FC%,{,#^FD5: {A, {B {d, {Y ({a, {m/{d/{y, {d {b {Y).^FS 
^FO370,660^A0N,14^FC%,{,#^FD6: #A, #B #d, #Y (#a, #m/#d/#y, #d #b #Y).^FS 

^FX// Cizgi        ^FS
^FO20,680^GB772,3,3^FS
^FO20,700^A0N,22,22^FDOzel Alanlar:^FS

^FX// Kutucuklar   ^FS
^FO20,740^GB150,80,2^FS
^FO35,755^A0N,18,18^FDKUTU 1^FS
^FO35,785^A0N,28,28^FDAKTIF^FS

^FO190,740^GB150,80,2^FS
^FO205,755^A0N,18,18^FDKUTU 2^FS
^FO205,785^A0N,28,28^FDPASIF^FS

^FO360,740^GB150,80,2^FS
^FO375,755^A0N,18,18^FDKUTU 3^FS
^FO375,785^A0N,28,28^FDBEKLEME^FS

^FO530,740^GB150,80,2^FS
^FO545,755^A0N,18,18^FDKUTU 4^FS
^FO545,785^A0N,28,28^FDTAMAM^FS

^FX// Alt serit      ^FS
^FO0,860^GB812,60,60^FS
^FO20,875^A0N,30,30^FR^FDTest ZPL v1.0 | Uretim Hatti: A-7 | Operator: TEST-KULLANICI^FS

^FX// MaxiCode       ^FS
^FO20,940^A0N,18,18^FDMaxiCode Mode 2 (UPS):^FS
^FO20,970^BD3^FH^FD066826RS19_5B)>_1E01_1D961Z00136111_1DUPSN_1D123X56_1D057_1D_1D001/001_1D011_1DN_1D_1DWEST SWINDON_1D_1E_04^FS

^FX// PDF417         ^FS
^BY2
^FO300,940^A0N,18,18^FDPDF417 (Yuksek Kapasite):^FS
^FO300,970^B7N,10,4,10,10^FDKARMASIK_TEST_VERISI_2026_BATCH_8847_LOT_9912_MUSTERI_4455^FS

^FX// Dipnot         ^FS
^FO20,1190^A0N,16,16^FDNot: Bu etiket test amaclidir. Tum barkodlar ve veriler ornek niteligindedir. | ZPL Karisik Test v1.0 (@) ARMAN^FS

^XZ
